[Zoeken][Index 1996][Threads 1996][Index 1998][Threads 1998]

[Date Prev][Date Next][Thread Prev][Thread Next][Datum index][Onderwerp index]

Re: wieltje spaken.



>Er moet ergens op het web een spoke langth calculator rondhangen.
>Marcel. Afgelopen zondag heb ik een spaak programma van mijn oom gekregen op msx formaat. Met de basic compiler van Dos 6 werkt dit prima. je kan er makkelijk zelf nog naven en velgen aan toevoegen. voor het gemak plak ik hem gewoon achter dit bericht. Veel plezier er mee. (heb ik ook)

1010 REM berekenen spaaklengte MSX2 V04, aangevuld door G. H. van Eck, Waalre 97-05
1020 KEY OFF:WIDTH 80:CLS:COLOR 15,4,4
1030 REM aangepast programma uit FIETS nr. 7 - 1987
1040 REM vullen naafgegevens
1050 DIM NO$(20),FR(20),FL(20),HR(20),HL(20),GA(20),VB(20)
1060 RESTORE 3120
1070 TE=0
1080 READ VN,N$,RF,LF,RH,LH,AG,BV
1090 IF VN = 99 GOTO 1130
1100 TE = TE + 1
1110 NO$(TE)=N$:FR(TE)=RF:FL(TE)=LF:HR(TE)=RH:HL(TE)=LH:GA(TE)=AG:VB(TE)=BV
1120 GOTO 1080
1130 REM
1140 REM vullen velgmaten
1150 DIM WN(20),WM(20),WO$(20)
1160 RESTORE 3370
1170 WE=0
1180 READ W1,W2,W3$
1190 IF W1 > 15 GOTO 1230
1200 WE = WE + 1
1210 WN(WE)=W1:WM(WE)=W2:WO$(WE)=W3$
1220 GOTO 1180
1230 REM
1240 CLS
1250 PRINT"Berekening van de spaaklengte"
1260 PRINT"aangepast programma uit FIETS no.7-1987"
1270 PRINT
1280 PRINT"Kies te gebruiken naaf :"
1290 PRINT" 0 zelf naafgegevens invullen"
1300 FOR T1 = 1 TO TE
1310 PRINT USING "##";T1;
1320 PRINT SPC(2);NO$(T1)
1330 NEXT T1
1340 PRINT
1350 INPUT"Kies de te gebruiken naaf 0 - 17 : ";NX
1360 IF NX = 0 GOTO 1400
1370 IF NX > 17 GOTO 1350
1380 NT$=NO$(NX):NR=FR(NX):NL=FL(NX):BL=HL(NX):BR=HR(NX):SP=GA(NX):IB=VB(NX)
1390 Y=0:GOTO 1530
1400 REM zelf naaf-gegevens invullen
1410 CLS
1420 PRINT"Zelf naaf-gegevens invullen"
1430 PRINT
1440 INPUT"Omschrijving van de naaf : ";NT$
1450 INPUT"Linker diameter naafflens in mm : ";NL
1460 INPUT"Rechter diameter naafflens in mm : ";NR
1470 INPUT"Linker naafflens-hartlijn vork in mm : ";BL
1480 INPUT"Rechter naafflens-hartlijn vork in mm : ";BR
1490 Y=0
1500 PRINT"aantal spaken in de naaf"
1510 INPUT" veelvoud van 4 (16 - 48) : ";SP
1520 REM bepaal mogelijk aantal kruizen
1530 IF SP = 16 THEN Y=1
1540 IF SP = 20 OR SP = 24 THEN Y=2
1550 IF SP = 28 OR SP = 32 THEN Y=3
1560 IF SP = 36 OR SP = 40 THEN Y=4
1570 IF SP = 44 OR SP = 48 THEN Y=5
1580 IF Y=0 GOTO 1500
1590 CLS
1600 REM berekenen spaaklengte, keuze velg
1610 CLS
1620 VG=0
1630 PRINT"Berekening van de spaaklengte, velgmaat"
1640 PRINT" normale velgen, holkamervelgen zelf invullen"
1650 PRINT
1660 PRINT"gekozen naaf : ";NT$;SPC(1);SP;" spaken"
1670 PRINT
1680 PRINT" ETRTO Handelsmaat inches"
1690 PRINT" 0 = zelf invullen "
1700 FOR V1 = 1 TO WE
1710 PRINT USING "###";V1;
1720 PRINT " = ";
1730 PRINT USING "###";WM(V1);
1740 PRINT " -> ";WO$(V1)
1750 NEXT V1
1760 GOTO 1770
1770 PRINT
1780 INPUT"Kies de velgmaat 0 - 15 ";VX
1790 IF VX= 0 GOTO 1870
1800 IF VX> 15 GOTO 1780
1810 VG=WM(VX):VT$=WO$(VX)
1820 CLS
1830 PRINT"ETRTO maat in mm: ";VG
1840 VE=VG
1850 VE=VE-12
1860 GOTO 1980
1870 REM zelf velg-gegevens invullen
1880 CLS
1890 PRINT"Zelf velg-gegevens invullen"
1900 PRINT
1910 INPUT"Omschrijving van de velg : ";VT$
1920 INPUT"ETRTO maat in mm: ";VG
1930 INPUT"velg diameter spaakgaten in mm: ";VE
1940 IF VG < VE THEN GOTO 1900
1950 DV$="-"
1960 GOTO 2020
1970 REM
1980 INPUT"gedopte velg j / n : ";DV$
1990 IF DV$ = "J" OR DV$ = "j" THEN VE=VE-2
2000 IF DV$ = "J" OR DV$ = "j" GOTO 2020
2010 DV$ = "n"
2020 CLS
2030 PRINT"Berekening van de spaaklengte"
2040 PRINT"aangepast programma uit FIETS no.7-1987"
2050 PRINT
2060 PRINT"Linker spaakdiam.naafflens(mm):";NL;SPC(2);NT$
2070 PRINT"Rechter spaakdiam.naafflens(mm):";NR
2080 PRINT"Linker naafflens-hartlijn (mm):";BL
2090 PRINT"Rechter naafflens-hartlijn (mm):";BR
2100 PRINT"aantal spaken :";SP;SPC(2);"max. kruis = ";Y
2110 PRINT"gedopte velg : ";DV$
2120 PRINT"velg diameter spaakgaten (mm) :";VE
2130 PRINT"ETRTO maat :";VG;SPC(2);VT$
2140 PRINT
2150 PRINT" diam *-kruis0-* *-kruis1-* *-kruis2-* *-kruis3-* *-kruis4-* *-kruis5-*"
2160 PRINT" velg L R L R L R L R L R L R"
2170 PRINT" mm mm mm mm mm mm mm mm mm mm mm mm mm"
2180 PRINT
2190 VA=VE - 4
2200 FOR VA = VA TO VA+8 STEP 2
2210 IF VA=VE THEN PRINT" "
2220 PRINT USING"#####";VA;
2230 REM kruis 0
2240 B2=.5*VA - .5*NR
2250 LR=SQR(B2*B2+BR*BR)
2260 B3=.5*VA - .5*NL
2270 LL=SQR(B3*B3+BL*BL)
2280 PRINT USING"#######";LL;
2290 PRINT USING"#####";LR;
2300 REM kruis 1 t/m 5
2310 FOR N= 1 TO Y STEP 1
2320 B1=.5*VA*SIN(N*12.5664/SP)
2330 B2=.5*VA*COS(N*12.5664/SP)-.5*NR
2340 LR=SQR(B1*B1+B2*B2+BR*BR)
2350 IF NA>=VA THEN LR=0
2360 B3=.5*VA*COS(N*12.5664/SP)-.5*NL
2370 LL=SQR(B1*B1+B3*B3+BL*BL)
2380 IF NA>=VA THEN LL=0
2390 PRINT USING"#######";LL;
2400 PRINT USING"#####";LR;
2410 NEXT N
2420 IF VA=VE THEN PRINT" "
2430 PRINT
2440 NEXT VA
2450 INPUT"afdrukken op Printer (J/N) :";P$
2460 IF P$="j" OR P$="J" THEN 2490
2470 END
2480 CLS
2490 LPRINT" Berekening van de spaaklengte"
2500 LPRINT" aangepast programma uit FIETS no.7-1987"
2510 LPRINT
2520 LPRINT" Linker spaakdiam.naafflens(mm):";NL;SPC(2);NT$
2530 LPRINT" Rechter spaakdiam.naafflens(mm):";NR
2540 LPRINT" Linker naafflens-hartlijn (mm):";BL
2550 LPRINT" Rechter naafflens-hartlijn (mm):";BR
2560 LPRINT" aantal spaken :";SP;SPC(2);"max. kruis = ";Y
2570 LPRINT" gedopte velg : ";DV$
2580 LPRINT" velg diameter spaakgaten (mm) :";VE
2590 LPRINT" ETRTO maat :";VG;SPC(2);VT$
2600 LPRINT
2610 LPRINT" diam *-kruis0-* *-kruis1-* *-kruis2-* *-kruis3-* *-kruis4-* *-kruis5-*"
2620 LPRINT" velg L R L R L R L R L R L R"
2630 LPRINT" mm mm mm mm mm mm mm mm mm mm mm mm mm"
2640 LPRINT
2650 VA=VE - 4
2660 FOR VA = VA TO VA+8 STEP 2
2670 IF VA=VE THEN LPRINT" "
2680 LPRINT USING"########";VA;
2690 REM kruis 0
2700 B2=.5*VA - .5*NR
2710 LR=SQR(B2*B2+BR*BR)
2720 B3=.5*VA - .5*NL
2730 LL=SQR(B3*B3+BL*BL)
2740 LPRINT USING"#######";LL;
2750 LPRINT USING"#####";LR;
2760 REM kruis 1 t/m 5
2770 FOR N= 1 TO Y STEP 1
2780 B1=.5*VA*SIN(N*12.5664/SP)
2790 B2=.5*VA*COS(N*12.5664/SP)-.5*NR
2800 LR=SQR(B1*B1+B2*B2+BR*BR)
2810 IF NA>=VA THEN LR=0
2820 B3=.5*VA*COS(N*12.5664/SP)-.5*NL
2830 LL=SQR(B1*B1+B3*B3+BL*BL)
2840 IF NA>=VA THEN LL=0
2850 LPRINT USING"#######";LL;
2860 LPRINT USING"#####";LR;
2870 NEXT N
2880 IF VA=VE THEN LPRINT" "
2890 LPRINT
2900 NEXT VA
2910 LPRINT
2920 LPRINT
2930 LPRINT
2940 LPRINT
2950 LPRINT
2960 LPRINT
2970 END
2980 REM Omschrijvingen naven
2990 REM NT$ = omschrijving van de naaf, zoals
3000 REM vw = voorwiel, aw = achterwiel
3010 REM
3020 REM NL = diameter spaakgaten linker naafflens
3030 REM NR = diameter spaakgaten rechter naafflens
3040 REM BL = afstand linker naafflens - hart vork
3050 REM BR = afstand rechter naafflens - hart vork
3060 REM SP = aantal spaakgaten van de naaf
3070 REM IB = inbouwbreedte naaf binnen de vork
3080 REM reeds bekende omschrijvingen naven
3090 REM nn,"Omschrijving van de naaf ", NL, NR, BL, BR, SP, IB
3100 REM
3110 REM 00,"12345678901234567890123456789012345",000,000,000,000,000,000
3120 DATA 01,"vw S A trommelrem oud ",103,051,028,028,036,100
3130 DATA 02,"aw S A trommelrem oud, 3-versn ",103,066,033,033,036,125
3140 DATA 03,"vw Shimano snelsluiting ",037,037,036,036,036,100
3150 DATA 04,"aw Shimano FH-HG50, deraill ",045,045,021,035,036,130
3160 DATA 05,"aw Sachs Orbit trommelrem, der.6-v ",088,088,019,037,036,128
3170 DATA 06,"vw naaf Roulandt 20 sp ",032,032,036,036,020,100
3180 DATA 07,"aw Sachs Komet terugtraprem ",053,053,028,028,036,114
3190 DATA 08,"aw Favorit terugtraprem ",053,053,028,028,036,114
3200 DATA 09,"aw Sachs lm trommelrem, 5-v ",090,090,030,030,026,128
3210 DATA 10,"vw Sachs lm trommelrem ",090,090,029,029,036,100
3220 DATA 11,"aw Sachs lm trommelrem, 3-v ",090,090,030,030,036,120
3230 DATA 12,"vw Sachs st trommelrem ",090,090,026,026,036,100
3240 DATA 13,"aw Shimano NEXUS rollercamrem, 7-v ",088,088,026,026,036,128
3250 DATA 14,"aw S A Elite ST trommelrem, der 5-v",090,090,018,040,036,125
3260 DATA 15,"vw S A Elite VT trommelrem ",090,090,028,028,036,100
3270 DATA 16,"aw S A Steelite trommelrem, 3-v ",083,066,028,028,036,120
3280 DATA 17,"vw S A Steelite trommelrem ",083,083,026,026,036,100
3290 DATA 99,"EINDE ",000,000,000,000,000,000
3300 REM
3310 REM
3320 REM Omschrijving velgmaten (ETRTO)
3330 REM NN volgnummer van de velg
3340 REM WWW ETRTO velgmaat
3350 REM NN,WWW,"Omschrijving velg-maat "
3360 REM
3370 DATA 01,203,"12 1/2 * 1.75 inch "
3380 DATA 02,298," 14 * 1 3/8 inch "
3390 DATA 03,305," 16 * 1.75 inch "
3400 DATA 04,340," 16 * 1 3/8 inch "
3410 DATA 05,355," 18 * 1.75 inch "
3420 DATA 06,387," 18 * 1 3/8 inch "
3430 DATA 07,406," 20 * 1.75 inch "
3440 DATA 08,438," 20 * 1 3/8 inch "
3450 DATA 09,507," 24 * 1.75 inch "
3460 DATA 10,540," 24 * 1 3/8 inch "
3470 DATA 11,559," 26 * 2 inch "
3480 DATA 12,590," 26 * 1 3/8 inch "
3490 DATA 13,622," 28 * 1 5/8 inch "
3500 DATA 14,630," 27 * inch "
3510 DATA 15,635," 28 * 1 1/2 inch "
3520 DATA 99,000," einde "







Archief homepage | Datum index | Onderwerp index